登录/注册
与非网论坛 »首页 › 厂商小组 › DFROBOT › 【CurieNano上手2】快速上手

赞

3回答

0收藏

[原创] 【CurieNano上手2】快速上手

DFROBOT DFROBOT 5071 人阅读 | 3 人回复 | 2017-05-03

本帖最后由 灯灯灯 于 2017-5-5 14:08 编辑


功能概览
相比Arduino Nano，CurieNano的优点有：运算速度快、更大的存储空间、运动传感器、电子罗盘、蓝牙4.0、硬件神经元、I2S接口、实时时钟、板载2MB SPIFlash空间、更高速的ADC、双串口、中断引脚多达20个。

型号 ArduinoNano CurieNano
微控制器 ATmega328P Intel Curie
时钟频率 16MHz32MHz
工作电压 5V 3.3V
数字引脚个数 14 14
PWN引脚个数 6 4
模拟输入引脚个数 6 6
中断引脚个数 2 20
串口数量 1 2
Flash空间 32KB 196KB
SRAM空间 2KB 24KB
独有特点 IMU,BLE,PME,I2S,RTC,SPIFlash






一些例程


以下我给出一些独有特性的测试例程（其实例程在Arduino IDE官方示例里面都有，只不过我写的更加精简）


1、运动传感器IMU

效果：在串口打印加速度计读值，即101三个方向上的加速度值（单位m/s^2）
  1. #include <CurieIMU.h>

  3. void setup() {
  4.   Serial.begin(9600);
  5.   CurieIMU.begin();
  6.   CurieIMU.setAccelerometerRange(2);
  7. }

  9. void loop() {
  10.   int ax, ay, az;
  11.   CurieIMU.readAccelerometer(ax, ay, az);
  12.   Serial.print((float)ax/16384);
  13.   Serial.print("\t");
  14.   Serial.print((float)ay/16384);
  15.   Serial.print("\t");
  16.   Serial.println((float)az/16384);
  17. }
复制代码
2、蓝牙BLE

效果：下载手机端的NRF toobox以后，选择HRM(HeartRateMonitor)，连接Arduino101，可以看到读值从0~255循环变化，每1秒变一次
  1. #include <CurieBLE.h>

  3. BLEPeripheral blePeripheral;
  4. BLEService S("180D");
  5. BLECharacteristic C("2A37", BLENotify, 2);

  7. void setup() {
  8.   blePeripheral.setLocalName("Arduino 101");
  9.   blePeripheral.setAdvertisedServiceUuid(S.uuid());
  10.   blePeripheral.addAttribute(S);
  11.   blePeripheral.addAttribute(C);
  12.   blePeripheral.begin();
  13. }

  15. uint8_t data[] = {0,0};

  17. void loop() {
  18.   data[1] ++;
  19.   C.setValue(data,2);
  20.   delay(1000);
  21. }
复制代码
3、实时时钟

效果：在串口打印实时时钟时间。注意：101每次断电重启时，时钟都会恢复最初值
  1. #include <CurieTime.h>

  3. void setup() {
  4.   Serial.begin(9600);
  5. }

  7. void loop() {
  8.   Serial.print(hour());Serial.write(':');
  9.   Serial.print(minute());Serial.write(':');
  10.   Serial.print(second());Serial.print("   ");
  11.   Serial.print(day());Serial.write('/');
  12.   Serial.print(month());Serial.write('/');
  13.   Serial.println(year());
  14.   delay(1000);
  15. }
复制代码
4、板载Flash

板载Flash大小为2MB，有一个固定文件大小的文件系统，每个文件在建立时就确定大小，之后不能改动，需要用到的库是SerialFlash，它是第三方的，需要去github下载github.com/PaulStoffregen/SerialFlash。以下是写入一个64B的文件的例程：

  1. #include <SerialFlash.h>
  2. #include <SPI.h>

  4. #define File_SIZE 64

  6. #define filename  "myfile.txt"

  8. char contents[] = "Arduino 101 serial flash file system test";

  10. // digital pin for flash chip CS pin
  11. #define g_FlashChipSelect 21

  13. void setup() {
  14.   Serial.begin(9600);
  15.   while(!Serial);
  16.   
  17.   if ( !SerialFlash.begin(g_FlashChipSelect) ){
  18.     Serial.println("Unable to access SPI Flash chip");
  19.   }

  21.   SerialFlashFile file;

  23.   if ( !SerialFlash.exists(filename)){
  24.     if(! SerialFlash.create(filename, File_SIZE)){
  25.       Serial.println("Not enough space to create file " filename);
  26.       return;
  27.     }
  28.     Serial.println("Creating file " filename);
  29.   }else{
  30.     Serial.println("File " filename " already exists");
  31.   }
  32.   
  33.   file = SerialFlash.open(filename);
  34.   file.write(contents, sizeof(contents));
  35.   Serial.println("Write Done");
  36. }

  38. void loop() {
  39.   SerialFlashFile file = SerialFlash.open(filename);
  40.   if(file){
  41.     char buf[sizeof(contents)];
  42.     Serial.println(filename ":");
  43.     file.read(buf,sizeof(contents));
  44.     Serial.println(buf);
  45.   }else{
  46.     Serial.println("File " filename " not exists");
  47.   }
  48.   delay(3000);
  49. }
复制代码

文件写入后，可以运行下面的程序，读出这个文件，显示在串口：

  1. #include <SerialFlash.h>
  2. #include <SPI.h>

  4. #define filename  "myfile.txt"

  6. #define g_FlashChipSelect 21

  8. void setup() {
  9.   Serial.begin(9600);
  10.   if ( !SerialFlash.begin(g_FlashChipSelect) ){
  11.     Serial.println("Unable to access SPI Flash chip");
  12.   }
  13. }

  15. void loop(){
  16.   SerialFlashFile file = SerialFlash.open(filename);
  17.   if(file){
  18.     char buf[64] = {0};
  19.     Serial.println(filename ":");
  20.     file.read(buf,64);
  21.     Serial.println(buf);
  22.   }else{
  23.     Serial.println("File " filename " not exists");
  24.   }
  25.   delay(3000);
  26. }
复制代码


5、外部中断

CurieNano的所有IO引脚都可用于外部中断。本程序监听14~17号引脚是否发生下降沿中断，发生时打印中断引脚号。

  1. void setup() {
  2.   attachInterrupt(14,intf14,FALLING);
  3.   attachInterrupt(15,intf15,FALLING);
  4.   attachInterrupt(16,intf16,FALLING);
  5.   attachInterrupt(17,intf17,FALLING);
  6.   interrupts();
  7.   Serial.begin(9600);
  8. }

  10. void intf14(){Serial.print("14 ");}
  11. void intf15(){Serial.print("15 ");}
  12. void intf16(){Serial.print("16 ");}
  13. void intf17(){Serial.print("17 ");}

  15. void loop() {}
复制代码


6、定时器中断

本程序每1秒触发一次定时器中断，将13号引脚电平反转，板载LED灯出现闪烁效果。
  1. #include <CurieTimerOne.h>

  3. void timeInterrupt(){
  4.   static uint8_t toggle = 0;
  5.   digitalWrite(13, toggle);
  6.   toggle = !toggle;
  7. }

  9. void setup() {
  10.   pinMode(13, OUTPUT);
  11.   CurieTimerOne.start(100000, &timeInterrupt);
  12. }

  14. void loop() {}
复制代码
7、分类算法
这就用到了Curie芯片的硬件神经元，需要在github下载第三方库CuriePME：github.com/01org/Intel-Pattern-Matching-Technology。以下的代码调用PME引擎，实现数据分类：
  1. #include <CuriePME.h>

  3. void setup(){
  4.   Serial.begin(9600);
  5.   Serial.setTimeout(0xffffffff);
  6.   while (!Serial);
  7.   CuriePME.begin();
  8.   trainNeuronsWithData();
  9. }

  11. void loop(){
  12.   uint8_t vector[2];
  13.   vector[0] = (uint8_t) Serial.parseInt();
  14.   vector[1] = (uint8_t) Serial.parseInt();
  15.   int answer = CuriePME.classify(vector, 2);
  16.   if( answer == CuriePME.noMatch ){
  17.     Serial.println("Didn't match any categories.");
  18.   }else{
  19.     Serial.print("The closest matching is category: ");
  20.     Serial.println(answer);
  21.   }
  22. }

  24. void trainNeuronsWithData(){
  25.   commitSamples(1, 11, 24);
  26.   commitSamples(2, 38, 75);
  27.   commitSamples(3, 2, 56);
  28.   commitSamples(4, 111, 224);
  29.   commitSamples(5, 128, 200);
  30.   commitSamples(6, 99, 180);
  31.   Serial.println("Now input 2 numbers, between 0 and 255, Like 30 24, then press enter, make sure a \\n or \\r sended after that.");
  32. }

  34. void commitSamples (int category, uint8_t s1, uint8_t s2){
  35.   uint8_t vector[2] = {s1,s2};
  36.   CuriePME.learn(vector, 2, category);
  37.   Serial.print("Category ");Serial.print( category );
  38.   Serial.print(" trained with: (");Serial.print(s1);Serial.print(",");Serial.print(s2);Serial.println(")");
  39. }
复制代码
收藏 转播 分享 顶 踩
分享到：
回复

使用道具 举报

回答|共 3 个

倒序浏览

沙发

jwdxu2009

发表于 2017-5-4 09:59:57 | 只看该作者

参考和学习，很适用
回复 支持 反对

使用道具 举报

板凳

slotg

发表于 2017-5-4 10:06:33 | 只看该作者

感谢分享，找块板子来试试了。
回复 支持 反对

使用道具 举报

地板

feixiang20

发表于 2017-12-22 10:24:52 | 只看该作者

这些例程有详细的么
回复 支持 反对

使用道具 举报

返回列表
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 注册/登录

本版积分规则

avatar
158 积分
12 主题
+ 关注
关闭

站长推荐上一条 /3 下一条

  • 手机版| 小黑屋|

? 2010 - 2025 苏州广东会网络科技有限公司 版权所有 ICP经营许可证 苏B2-20140176 | 苏ICP备14012660号-6 | 苏公网安备 32059002001874号